home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1999 #2 / Amiga Plus CD - 1999 - No. 2.iso / System-Boost / Workbench / Archive / lharchie / Install < prev    next >
Text File  |  1998-11-08  |  5KB  |  173 lines
  1. ;$VER: LHArchie Install Script V2.00 (01.11.1998)
  2. ;Written by Matthias Grosser
  3. ;Copyright ©1996-98 Matthias Grosser
  4. ;Not for commercial use - All rights reserved.
  5.  
  6. (complete 0)
  7. (set @appname "LHArchie V3.20")
  8. (set #currentVer "3.20")
  9.  
  10. (message "\n\nLHArchie Version "#currentVer"\n"
  11.          "Installationsskript V2.00\n\n"
  12.          "Im folgenden wird LHArchie auf Ihrem Amiga installiert.\n\n"
  13.          "Copyright © 1995-98 Matthias Grosser\n"
  14.          "Alle Rechte vorbehalten."
  15. )
  16.  
  17. (set #Source (cat ""))
  18.  
  19. (set #WorkingMsg
  20.  (cat "\n\nBitte warten...  Installation wird durchgeführt"
  21. ))
  22.  
  23. ; get information
  24.  
  25. (set #lang
  26.  (askoptions
  27.   (prompt "\nWelche Catalogs sollen installiert werden?\n")
  28.   (choices "deutsch" "français" "español")
  29.   (default %001)
  30.   (help "Wenn Sie einen bestimmten Catalog installieren, wird die jeweilige "
  31.         "Sprache von LHArchie verwendet, falls sie im Locale-Voreinsteller "
  32.         "ausgewählt ist. Falls keine Catalogs installiert werden, "
  33.         "wird LHArchie Englisch als Sprache verwenden."
  34. )))
  35.  
  36. (if (= #lang %000) ;falls keine Catalogs..
  37.  (set #toolt
  38.   (askbool
  39.    (prompt "\nSie haben keine Catalogs ausgewählt. Soll das Programmerkmal "
  40.            "\"FORCEENGLISH\" gesetzt werden ? ")
  41.    (default 0)                                                               
  42.    (help "Wenn Sie \"Ja\" wählen, wird das LHArchie-Programmerkmal "
  43.          "\"FORCEENGLISH\" gesetzt. Wenn es gesetzt ist, verwendet LHArchie "
  44.          "stets English als Programmsprache. Dies kann sinnvoll sein, falls "
  45.          "keine Catalogs installiert sind und deswegen beim Programmstart "
  46.          "ein Hinweis erscheint. Sie können das Merkmal auch selbst aktivieren, "
  47.          "indem Sie die Piktogramminformationen von der Workbench aus verändern. "
  48. ))))
  49.  
  50. (if (= @user-level 1) ;average
  51.  ((set #DestDrawer
  52.    (askdir
  53.     (prompt "Bitte wählen Sie das Verzeichnis, in dem "
  54.             "die LHArchie-Schublade angelegt werden soll.")
  55.     (help @askdir-help)
  56.     (default "SYS:Tools")
  57.   ))
  58.   (set #directory #DestDrawer)
  59.   (set #drawername "LHArchie")
  60.   (set @default-dest (tackon #DestDrawer #drawername))
  61.   (set #helpdest @default-dest)
  62.   (set #defdestdrawericon (cat @default-dest ".info"))
  63.   (set #helpicon (tackon @default-dest "LHArchie.guide.info"))
  64.   (set #progicon (tackon @default-dest "LHArchie.info"))
  65.   (set #localedest (tackon @default-dest "catalogs"))
  66.   (set #deutsch (tackon #localedest "deutsch"))
  67.   (set #français (tackon #localedest "français"))
  68.   (set #español (tackon #localedest "español"))
  69.   (makedir @default-dest (infos))
  70. ))
  71.  
  72. (if (= @user-level 2) ;expert
  73.  ((set @default-dest
  74.    (askdir
  75.     (prompt "Bitte wählen Sie das Verzeichnis, in das LHArchie "
  76.             "kopiert werden soll.")
  77.     (help @askdir-help)
  78.     (default "SYS:Tools")
  79.   ))
  80.   (set #helpdest @default-dest)
  81.   (set #helpdest
  82.    (askdir
  83.     (prompt "Bitte wählen Sie das Verzeichnis, in das die Hilfedatei "
  84.             "kopiert werden soll.")
  85.     (help @askdir-help)
  86.     (default #helpdest)
  87.   ))
  88.   (if (<> #lang %000)
  89.    ((set #localedest
  90.      (askdir
  91.       (prompt "Bitte wählen Sie das Verzeichnis, in dem das Catalogs-"
  92.               "Verzeichnis angelegt werden soll bzw. bereits vorhanden ist.")
  93.       (help @askdir-help)
  94.       (default @default-dest)
  95.     ))
  96.     (set #localedest (tackon #localedest "catalogs"))
  97.     (set #deutsch (tackon #localedest "deutsch"))
  98.     (set #français (tackon #localedest "français"))
  99.     (set #español (tackon #localedest "español"))
  100.   ))
  101.   (set #helpicon (tackon #helpdest "LHArchie.guide"))
  102.   (set #progicon (tackon @default-dest "LHArchie"))
  103. ))
  104.  
  105. ;Installation
  106.  
  107. (working #WorkingMsg)
  108. (complete 0)
  109.  
  110. (copyfiles
  111.  (source #Source)
  112.  (dest @default-dest)
  113.  (pattern "LHArchie")
  114.  (infos)
  115. )
  116.  
  117. (complete 50)
  118.  
  119. (copyfiles
  120.  (source "LHArchie.guide")
  121.  (dest #helpdest)
  122.  (infos)
  123. )
  124.  
  125. (complete 80)
  126.  
  127. (if (<> #lang %000)
  128.  ((makedir #localedest)
  129.   (if (BITAND #lang %001) ;deutsch
  130.    ((makedir #deutsch)
  131.     (copyfiles
  132.      (source "catalogs/deutsch/LHArchie.catalog")
  133.      (dest #deutsch)
  134.   )))
  135.   (if (BITAND #lang %010) ;francais
  136.    ((makedir #français)
  137.     (copyfiles
  138.      (source "catalogs/français/LHArchie.catalog")
  139.      (dest #français)
  140.   )))
  141.   (if (BITAND #lang %100) ;espanol
  142.    ((makedir #español)
  143.     (copyfiles
  144.      (source "catalogs/español/LHArchie.catalog")
  145.      (dest #español)
  146.   )))
  147. ))
  148.  
  149. (if (= #toolt 1) ;keine Catalogs
  150.  ((set #lharchie (tackon @default-dest "LHArchie"))
  151.   (tooltype
  152.    (dest #lharchie)
  153.    (settooltype "FORCEENGLISH" "")
  154. )))
  155.  
  156. (complete 90)
  157.  
  158. (working "\n\nAnordnen der Piktogramme...")
  159.  
  160. (if (= @user-level 1) ;average
  161.  ((run (cat "IconPos \"" #defdestdrawericon "\" FREEX FREEY DXPOS 228 DYPOS 31 DWIDTH 147 DHEIGHT 112"))
  162.   (run (cat "IconPos \"" #progicon "\" 29 5"))
  163.   (run (cat "IconPos \"" #helpicon "\" 39 45"))
  164. ))
  165. (if (= @user-level 2) ;expert
  166.  ((run (cat "IconPos \"" #progicon "\" FREEX FREEY"))
  167.   (run (cat "IconPos \"" #helpicon "\" FREEX FREEY"))
  168. ))
  169.  
  170. (complete 100)
  171. (exit "Die Anleitung zum Programm finden sie in der Datei "
  172.       "LHArchie.guide.")
  173.